Angus Johnson's Delphi Tips

February 2012
    Get Version

January 2007
    Bezier Text

December 2005
    Rotated Ellipses

December 2004
    PDF Page Count

January 2003
    Boolean Blues

March 2002
    Networked Drives

January 2002
» Treeview Troubles
    Appending to Exe's

Freeware Components

Having used Delphi since Delphi 1, I had come to assume that using array properties was always very fast (ie constant irrespective of the size of the array - O(1) using Big-Oh notation). The TList.Items[] and the TStrings.Strings[] properties are good examples of this fast array access.

For readers who are wondering why they've never seen the Items property of TList or the Strings property of TStrings, Object Pascal allows an array property to be declared as the 'default' array for its class. This allows the array identifier to be omitted when accessing an object's default array. Hence MyList.Items[0] is equivalent to MyList[0], MyStringlist.Strings[0] is equivalent to MyStringlist[0] and MyTreeview.Items.Item[0] is equivalent to MyTreeview.Items[0]. (See "Default (directive)" in Delphi's online help for more info.)

Anyhow, assuming that object arrays will return in constant time is a mistake. The TTreeview.Items.Item[] property recently tripped me up as it turns out to have O(n) performance (and a cursory inspection of the TTreeNodes.GetNodeFromIndex() function in the ComCtrls unit reveals why). The TTreeNode.AbsoluteIndex property also has O(n) performance and should be avoided if possible (eg by incrementing your own index counter when enumerating a range of treeview items).

Below is a trivial demonstration of the problem I encountered by assuming TTreeview.Items.Item 's performance.

[ To run the code below requires placing a treeview control and two buttons on the main form of a new project and implementing the following methods... ]

Code snippet ...

procedure TForm1.FormCreate(Sender: TObject);
var
  i: integer;
begin
  //populate the treeview control...
  with treeview1.items do
  begin
    beginupdate;
    for i := 1 to 2000 do
      AddChild(nil, inttostr(i));
    endupdate;
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  i: integer;
begin
  //watch how this slows down as the loop proceeds...
  //have a cup of tea handy if you have a slow processor :)
  with treeview1 do
    for i := 0 to items.count-1 do
    begin
      caption := items[i].Text;
    end;
end;

procedure TForm1.Button2Click(Sender: TObject);
var
  currentNode: TTreeNode;
begin
  //by avoiding the relatively slow Items.Item[] property
  //accessing individual treeview nodes can be very fast...
  with treeview1 do
  begin
    currentNode := items.GetFirstNode;
    while assigned(currentNode) do
    begin
      caption := currentNode.Text;
      currentNode := currentNode.GetNext;
    end;
  end;
end;